1: /*
2: *----------------------------------------------------------------------
3: * micro T-Kernel 3.00.00
4: *
5: * Copyright (C) 2006-2019 by Ken Sakamura.
6: * This software is distributed under the T-License 2.1.
7: *----------------------------------------------------------------------
8: *
9: * Released by TRON Forum(http://www.tron.org) at 2019/12/11.
10: *
11: *----------------------------------------------------------------------
12: */
13:
14: /*
15: * tkernel_map.ld
16: * micro T-Kernel linker script
17: */
18:
19: OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
20: OUTPUT_ARCH(arm)
21:
22: ENTRY(__start)
23:
24: SECTIONS {
25: .text 0x00000000 : {
26: __vector_org = .;
27: *(.vector)
28: __start = .;
29: *(.text)
30: *(.text.*)
31: *(.rodata)
32: *(.rodata.*)
33: . = ALIGN(0x10);
34: } =0
35: . = ALIGN(4);
36: __data_org = .;
37: vector 0x20000800 (NOLOAD) : {
38: __vector_start = .;
39: *(.data_vector)
40: __vector_end = .;
41: }
42: .data : AT(__data_org) {
43: __data_start = .;
44: *(.data)
45: *(.data.*)
46: . = ALIGN(4);
47: __data_end = .;
48: }
49: .bss ALIGN(4) (NOLOAD) : {
50: __bss_start = .;
51: PROVIDE (__noinit_start = .);
52: *(.noinit)
53: PROVIDE (__noinit_end = .);
54: *(.bss)
55: *(.bss.*)
56: *(COMMON)
57: . = ALIGN(4);
58: __bss_end = .;
59: __end = .;
60: }
61: }
62: