1: /*
2: *----------------------------------------------------------------------
3: * T-Kernel 2.0 Software Package
4: *
5: * Copyright 2011 by Ken Sakamura.
6: * This software is distributed under the latest version of T-License 2.x.
7: *----------------------------------------------------------------------
8: *
9: * Released by T-Engine Forum(http://www.t-engine.org/) at 2011/05/17.
10: * Modified by T-Engine Forum at 2013/03/11.
11: * Modified by TRON Forum(http://www.tron.org/) at 2015/06/01.
12: *
13: *----------------------------------------------------------------------
14: */
15:
16: /*
17: * kernel-ram.lnk (sysmain, EM1-D512)
18: * linker script (RAM)
19: */
20:
21: OUTPUT_FORMAT("elf32-larm-tkernel", "elf32-barm-tkernel", "elf32-larm-tkernel")
22: OUTPUT_ARCH(arm)
23: ENTRY(_start)
24:
25: SECTIONS
26: {
27: .text 0x30006000 : {
28: KEEP (*(.init))
29: *(.text)
30: *(.text.*)
31: *(.stub)
32: *(.glue_7t)
33: *(.glue_7)
34: KEEP (*(.fini))
35: PROVIDE (__etext = .);
36: PROVIDE (_etext = .);
37: PROVIDE (etext = .);
38: *(.rodata)
39: *(.rodata.*)
40: *(.rodata1)
41: . = ALIGN(0x1000);
42: } /*:text*/ =0
43: __data_org = . ;
44: .data ALIGN(0x10) : {
45: __data_start = . ;
46: *(.data)
47: *(.data.*)
48: SORT(CONSTRUCTORS)
49: *(.data1)
50: KEEP (*(.eh_frame))
51: *(.gcc_except_table)
52: KEEP (*crtbegin.o(.ctors))
53: KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
54: KEEP (*(SORT(.ctors.*)))
55: KEEP (*(.ctors))
56: KEEP (*crtbegin.o(.dtors))
57: KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
58: KEEP (*(SORT(.dtors.*)))
59: KEEP (*(.dtors))
60: *(.got.plt)
61: *(.got)
62: *(.sdata)
63: *(.sdata.*)
64: _edata = .;
65: PROVIDE (edata = .);
66: } /*:data*/
67: .bss : {
68: __bss_start = .;
69: PROVIDE (__sbss_start = .);
70: PROVIDE (___sbss_start = .);
71: *(.sbss)
72: *(.sbss.*)
73: *(.scommon)
74: PROVIDE (__sbss_end = .);
75: PROVIDE (___sbss_end = .);
76: *(.bss)
77: *(.bss.*)
78: *(COMMON)
79: . = ALIGN(4);
80: _end = .;
81: PROVIDE (end = .);
82: } /*:data*/
83: }