1: /*
2: *----------------------------------------------------------------------
3: * T-Kernel 2.0 Software Package
4: *
5: * Copyright 2011 by Ken Sakamura.
6: * This software is distributed under the latest version of T-License 2.x.
7: *----------------------------------------------------------------------
8: *
9: * Released by T-Engine Forum(http://www.t-engine.org/) at 2011/05/17.
10: * Modified by TRON Forum(http://www.tron.org/) at 2015/06/01.
11: *
12: *----------------------------------------------------------------------
13: */
14:
15: /*
16: * kernel-rom.lnk (sysmain, EM1-D512)
17: * linker script (ROM)
18: */
19:
20: OUTPUT_FORMAT("elf32-larm-tkernel", "elf32-barm-tkernel", "elf32-larm-tkernel")
21: OUTPUT_ARCH(arm)
22: ENTRY(_start)
23:
24: SECTIONS {
25: .text 0x70030000 : {
26: KEEP (*(.init))
27: *(.text)
28: *(.text.*)
29: *(.stub)
30: KEEP (*(.fini))
31: PROVIDE (__etext = .);
32: PROVIDE (_etext = .);
33: PROVIDE (etext = .);
34: *(.rodata)
35: *(.rodata.*)
36: *(.rodata1)
37: . = ALIGN(0x10);
38: } =0
39: __data_org = . ;
40: .data 0x30006000 : AT(__data_org) {
41: __data_start = . ;
42: *(.data)
43: *(.data.*)
44: SORT(CONSTRUCTORS)
45: *(.data1)
46: KEEP (*(.eh_frame))
47: *(.gcc_except_table)
48: KEEP (*crtbegin.o(.ctors))
49: KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
50: KEEP (*(SORT(.ctors.*)))
51: KEEP (*(.ctors))
52: KEEP (*crtbegin.o(.dtors))
53: KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
54: KEEP (*(SORT(.dtors.*)))
55: KEEP (*(.dtors))
56: *(.sdata)
57: *(.sdata.*)
58: . = ALIGN(4);
59: _edata = .;
60: PROVIDE (edata = .);
61: }
62: .bss ALIGN(4) : {
63: __bss_start = .;
64: PROVIDE (__sbss_start = .);
65: PROVIDE (___sbss_start = .);
66: *(.sbss)
67: *(.sbss.*)
68: *(.scommon)
69: PROVIDE (__sbss_end = .);
70: PROVIDE (___sbss_end = .);
71: *(.bss)
72: *(.bss.*)
73: *(COMMON)
74: . = ALIGN(4);
75: _end = .;
76: PROVIDE (end = .);
77: }
78: }